summaryrefslogtreecommitdiffstats
path: root/firmware/target/arm/imx233/app.lds
diff options
context:
space:
mode:
authorAmaury Pouly <pamaury@rockbox.org>2011-07-23 11:45:22 +0000
committerAmaury Pouly <pamaury@rockbox.org>2011-07-23 11:45:22 +0000
commiteb90d956935019f577311ebc7aec3a7898d76019 (patch)
treec4ac810faaf390b9020c46dc2197008679099034 /firmware/target/arm/imx233/app.lds
parent06c94740e510d0ce04e069f34631a0539e9e6742 (diff)
downloadrockbox-eb90d956935019f577311ebc7aec3a7898d76019.tar.gz
rockbox-eb90d956935019f577311ebc7aec3a7898d76019.tar.bz2
rockbox-eb90d956935019f577311ebc7aec3a7898d76019.zip
imx233/fuze+: huge rework
- enable MMU -rework lcd frame buffer - add rtc/adc/power stubs (or not) - fix a few MMC related defines (hopefully) - implement cache handling for DMA - more SD work - add keymap (based on clip) - add virtual buttons - update linker scripts - big step toward apps actually compiling git-svn-id: svn://svn.rockbox.org/rockbox/trunk@30200 a1c6a512-1295-4272-9138-f99709370657
Diffstat (limited to 'firmware/target/arm/imx233/app.lds')
-rw-r--r--firmware/target/arm/imx233/app.lds119
1 files changed, 119 insertions, 0 deletions
diff --git a/firmware/target/arm/imx233/app.lds b/firmware/target/arm/imx233/app.lds
new file mode 100644
index 0000000000..66d0b04391
--- /dev/null
+++ b/firmware/target/arm/imx233/app.lds
@@ -0,0 +1,119 @@
+#include "config.h"
+#include "cpu.h"
+
+ENTRY(start)
+OUTPUT_FORMAT(elf32-littlearm)
+OUTPUT_ARCH(arm)
+STARTUP(target/arm/imx233/crt0.o)
+
+#define PLUGINSIZE PLUGIN_BUFFER_SIZE
+#define CODECSIZE CODEC_SIZE
+
+#define DRAMORIG DRAM_ORIG
+#define IRAMORIG IRAM_ORIG
+
+#define IRAMSIZE (IRAM_SIZE - TTB_SIZE)
+
+#define DRAMSIZE (DRAM_SIZE - PLUGINSIZE - CODECSIZE - FRAME_SIZE)
+
+/* End of the audio buffer, where the codec buffer starts */
+#define ENDAUDIOADDR (DRAMORIG + DRAMSIZE)
+
+/* Where the codec buffer ends, and the plugin buffer starts */
+#define ENDADDR (ENDAUDIOADDR + CODEC_SIZE)
+
+/* INIT section is the codec buffer */
+#define INITSIZE CODEC_SIZE
+#define INITSTART ENDAUDIOADDR
+
+MEMORY
+{
+ IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
+ DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
+}
+
+SECTIONS
+{
+ .text :
+ {
+ loadaddress = .;
+ _loadaddress = .;
+ *(.text*)
+ } > DRAM
+
+ .data :
+ {
+ *(.data*)
+ *(.rodata*)
+ _dataend = . ;
+ } > DRAM
+
+ .iram :
+ {
+ _iramstart = .; // always 0
+ *(.vectors)
+ KEEP(*(.vectors));// otherwise there are no references to it and the linker strip it
+ *(.icode)
+ *(.irodata)
+ *(.idata)
+ . = ALIGN(0x4);
+ _iramend = .;
+ } > IRAM AT> DRAM
+
+ _iramcopy = LOADADDR(.iram);
+
+ .ibss (NOLOAD) :
+ {
+ _iedata = .;
+ *(.qharray)
+ *(.ibss)
+ . = ALIGN(0x4);
+ _iend = .;
+ } > IRAM
+
+ .init ENDAUDIOADDR :
+ {
+ . = ALIGN(4);
+ _initstart = .;
+ *(.init)
+ _initend = .;
+ } AT> DRAM
+
+ _initcopy = LOADADDR(.init);
+
+ .stack (NOLOAD) :
+ {
+ *(.stack)
+ stackbegin = .;
+ . += 0x2000;
+ stackend = .;
+ } > DRAM
+
+ .bss (NOLOAD) :
+ {
+ _edata = .;
+ *(.bss*);
+ _end = .;
+ } > DRAM
+
+ .audiobuf (NOLOAD) :
+ {
+ . = ALIGN(4);
+ _audiobuffer = .;
+ audiobuffer = .;
+ } > DRAM
+
+ .codec ENDAUDIOADDR (NOLOAD) :
+ {
+ audiobufend = .;
+ _audiobufend = .;
+ codecbuf = .;
+ _codecbuf = .;
+ } > DRAM
+
+ .plugin ENDADDR (NOLOAD) :
+ {
+ _pluginbuf = .;
+ pluginbuf = .;
+ }
+}