summaryrefslogtreecommitdiffstats
path: root/firmware/target
diff options
context:
space:
mode:
authorDave Chapman <dave@dchapman.com>2007-04-06 09:34:13 +0000
committerDave Chapman <dave@dchapman.com>2007-04-06 09:34:13 +0000
commit4303ab02a3efbd6a77e809641617c53082f9366f (patch)
tree73b2bde0cb847785981b69dc749d7223d2ae7a12 /firmware/target
parent31d8068b331af435c50cacfbb0ed2de1c2221f4d (diff)
downloadrockbox-4303ab02a3efbd6a77e809641617c53082f9366f.tar.gz
rockbox-4303ab02a3efbd6a77e809641617c53082f9366f.zip
Optimized lcd_yuv_blit() (used by mpegplayer) for the Sansa E200. This is just a copy-and-paste of the Gigabeat version by Michael Sevakis with no attempt to adapt to the different CPU in the E200 - so there could be room for further improvement. Reported to increase the FPS for the 224x128 version of Elephants Dream from 21fps to 27fps.
git-svn-id: svn://svn.rockbox.org/rockbox/trunk@13042 a1c6a512-1295-4272-9138-f99709370657
Diffstat (limited to 'firmware/target')
-rw-r--r--firmware/target/arm/sandisk/sansa-e200/lcd-as-e200.S222
-rw-r--r--firmware/target/arm/sandisk/sansa-e200/lcd-e200.c138
2 files changed, 256 insertions, 104 deletions
diff --git a/firmware/target/arm/sandisk/sansa-e200/lcd-as-e200.S b/firmware/target/arm/sandisk/sansa-e200/lcd-as-e200.S
new file mode 100644
index 0000000000..9e130cf54b
--- /dev/null
+++ b/firmware/target/arm/sandisk/sansa-e200/lcd-as-e200.S
@@ -0,0 +1,222 @@
+/***************************************************************************
+ * __________ __ ___.
+ * Open \______ \ ____ ____ | | _\_ |__ _______ ___
+ * Source | _// _ \_/ ___\| |/ /| __ \ / _ \ \/ /
+ * Jukebox | | ( <_> ) \___| < | \_\ ( <_> > < <
+ * Firmware |____|_ /\____/ \___ >__|_ \|___ /\____/__/\_ \
+ * \/ \/ \/ \/ \/
+ * $Id$
+ *
+ * Copyright (C) 2007 by Michael Sevakis
+ *
+ * All files in this archive are subject to the GNU General Public License.
+ * See the file COPYING in the source tree root for full license agreement.
+ *
+ * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
+ * KIND, either express or implied.
+ *
+ ****************************************************************************/
+
+#include "config.h"
+#include "cpu.h"
+
+/****************************************************************************
+ * void lcd_write_yuv_420_lines(fb_data *dst,
+ * unsigned char chroma_buf[LCD_HEIGHT/2*3],
+ unsigned char const * const src[3],
+ * int width,
+ * int stride);
+ *
+ * |R| |1.000000 -0.000001 1.402000| |Y'|
+ * |G| = |1.000000 -0.334136 -0.714136| |Pb|
+ * |B| |1.000000 1.772000 0.000000| |Pr|
+ * Scaled, normalized, rounded and tweaked to yield RGB 565:
+ * |R| |74 0 101| |Y' - 16| >> 9
+ * |G| = |74 -24 -51| |Cb - 128| >> 8
+ * |B| |74 128 0| |Cr - 128| >> 9
+ */
+ .section .icode, "ax", %progbits
+ .align 2
+ .global lcd_write_yuv420_lines
+ .type lcd_write_yuv420_lines, %function
+lcd_write_yuv420_lines:
+ @ r0 = dst
+ @ r1 = chroma_buf
+ @ r2 = yuv_src
+ @ r3 = width
+ @ [sp] = stride
+ stmdb sp!, { r4-r12, lr } @ save non-scratch
+ stmdb sp!, { r0, r3 } @ save dst and width
+ mov r14, #74 @ r14 = Y factor
+ ldmia r2, { r4, r5, r6 } @ r4 = yuv_src[0] = Y'_p
+ @ r5 = yuv_src[1] = Cb_p
+ @ r6 = yuv_src[2] = Cr_p
+10: @ loop line 1 @
+ ldrb r2, [r4], #1 @ r2 = *Y'_p++;
+ ldrb r8, [r5], #1 @ r8 = *Cb_p++;
+ ldrb r11, [r6], #1 @ r11 = *Cr_p++;
+ @
+ @ compute Y
+ sub r2, r2, #16 @ r7 = Y = (Y' - 16)*74
+ mul r7, r2, r14 @
+ @
+ sub r8, r8, #128 @ Cb -= 128
+ sub r11, r11, #128 @ Cr -= 128
+ @
+ mvn r2, #24 @ compute guv
+ mul r10, r2, r8 @ r10 = Cb*-24
+ mvn r2, #51 @
+ mla r10, r2, r11, r10 @ r10 = r10 + Cr*-51
+ @
+ mov r2, #101 @ compute rv
+ mul r9, r11, r2 @ r9 = rv = Cr*101
+ @
+ @ store chromas in line buffer
+ add r8, r8, #2 @ bu = (Cb + 2) >> 2
+ mov r8, r8, asr #2 @
+ strb r8, [r1], #1 @
+ add r9, r9, #256 @ rv = (Cr + 256) >> 9
+ mov r9, r9, asr #9 @
+ strb r9, [r1], #1 @
+ mov r10, r10, asr #8 @ guv >>= 8
+ strb r10, [r1], #1 @
+ @ compute R, G, and B
+ add r2, r8, r7, asr #9 @ r2 = b = (Y >> 9) + bu
+ add r11, r9, r7, asr #9 @ r11 = r = (Y >> 9) + rv
+ add r7, r10, r7, asr #8 @ r7 = g = (Y >> 8) + guv
+ @
+ orr r12, r2, r11 @ check if clamping is needed...
+ orr r12, r12, r7, asr #1 @ ...at all
+ cmp r12, #31 @
+ bls 15f @ no clamp @
+ mov r12, #31 @
+ cmp r12, r2 @ clamp b
+ andlo r2, r12, r2, asr #31 @
+ eorlo r2, r2, r12 @
+ cmp r12, r11 @ clamp r
+ andlo r11, r12, r11, asr #31 @
+ eorlo r11, r11, r12 @
+ cmp r12, r7, asr #1 @ clamp g
+ andlo r7, r12, r7, asr #31 @
+ eorlo r7, r7, r12 @
+ orrlo r7, r7, r7, asl #1 @
+15: @ no clamp @
+ @
+ orr r12, r2, r7, lsl #5 @ r4 |= (g << 5)
+ ldrb r2, [r4], #1 @ r2 = Y' = *Y'_p++
+ orr r12, r12, r11, lsl #11 @ r4 = b | (r << 11)
+ strh r12, [r0], #LCD_WIDTH @ store pixel
+ @
+ sub r2, r2, #16 @ r7 = Y = (Y' - 16)*74
+ mul r7, r2, r14 @ next Y
+ @ compute R, G, and B
+ add r2, r8, r7, asr #9 @ r2 = b = (Y >> 9) + bu
+ add r11, r9, r7, asr #9 @ r11 = r = (Y >> 9) + rv
+ add r7, r10, r7, asr #8 @ r7 = g = (Y >> 8) + guv
+ @
+ orr r12, r2, r11 @ check if clamping is needed...
+ orr r12, r12, r7, asr #1 @ ...at all
+ cmp r12, #31 @
+ bls 15f @ no clamp @
+ mov r12, #31 @
+ cmp r12, r2 @ clamp b
+ andlo r2, r12, r2, asr #31 @
+ eorlo r2, r2, r12 @
+ cmp r12, r11 @ clamp r
+ andlo r11, r12, r11, asr #31 @
+ eorlo r11, r11, r12 @
+ cmp r12, r7, asr #1 @ clamp g
+ andlo r7, r12, r7, asr #31 @
+ eorlo r7, r7, r12 @
+ orrlo r7, r7, r7, asl #1 @
+15: @ no clamp @
+ @
+ orr r12, r2, r11, lsl #11 @ r4 = b | (r << 11)
+ orr r12, r12, r7, lsl #5 @ r4 |= (g << 5)
+ strh r12, [r0, #LCD_WIDTH]! @ store pixel
+ add r0, r0, #2*LCD_WIDTH @
+ @
+ subs r3, r3, #2 @
+ bgt 10b @ loop line 1 @
+ @ do second line
+ @
+ ldmia sp!, { r0, r3 } @ pop dst and width
+ sub r0, r0, #2 @ set dst to start of next line
+ sub r1, r1, r3, asl #1 @ rewind chroma pointer...
+ ldr r2, [sp, #40] @ r2 = stride
+ add r1, r1, r3, asr #1 @ ... (r1 -= width/2*3)
+ @ move sources to start of next line
+ sub r2, r2, r3 @ r2 = skip = stride - width
+ add r4, r4, r2 @ r4 = Y'_p + skip
+ @
+20: @ loop line 2 @
+ ldrb r2, [r4], #1 @ r7 = Y' = *Y'_p++
+ ldrsb r8, [r1], #1 @ reload saved chromas
+ ldrsb r9, [r1], #1 @
+ ldrsb r10, [r1], #1 @
+ @
+ sub r2, r2, #16 @ r2 = Y = (Y' - 16)*74
+ mul r7, r2, r14 @
+ @ compute R, G, and B
+ add r2, r8, r7, asr #9 @ r2 = b = (Y >> 9) + bu
+ add r11, r9, r7, asr #9 @ r11 = r = (Y >> 9) + rv
+ add r7, r10, r7, asr #8 @ r7 = g = (Y >> 8) + guv
+ @
+ orr r12, r2, r11 @ check if clamping is needed...
+ orr r12, r12, r7, asr #1 @ ...at all
+ cmp r12, #31 @
+ bls 25f @ no clamp @
+ mov r12, #31 @
+ cmp r12, r2 @ clamp b
+ andlo r2, r12, r2, asr #31 @
+ eorlo r2, r2, r12 @
+ cmp r12, r11 @ clamp r
+ andlo r11, r12, r11, asr #31 @
+ eorlo r11, r11, r12 @
+ cmp r12, r7, asr #1 @ clamp g
+ andlo r7, r12, r7, asr #31 @
+ eorlo r7, r7, r12 @
+ orrlo r7, r7, r7, asl #1 @
+25: @ no clamp @
+ @
+ orr r12, r2, r11, lsl #11 @ r4 = b | (r << 11)
+ ldrb r2, [r4], #1 @ r2 = Y' = *Y'_p++
+ orr r12, r12, r7, lsl #5 @ r4 |= (g << 5)
+ strh r12, [r0], #LCD_WIDTH @ store pixel
+ @
+ @ do second pixel
+ @
+ sub r2, r2, #16 @ r2 = Y = (Y' - 16)*74
+ mul r7, r2, r14 @
+ @ compute R, G, and B
+ add r2, r8, r7, asr #9 @ r2 = b = (Y >> 9) + bu
+ add r11, r9, r7, asr #9 @ r11 = r = (Y >> 9) + rv
+ add r7, r10, r7, asr #8 @ r7 = g = (Y >> 8) + guv
+ @
+ orr r12, r2, r11 @ check if clamping is needed...
+ orr r12, r12, r7, asr #1 @ ...at all
+ cmp r12, #31 @
+ bls 25f @ no clamp @
+ mov r12, #31 @
+ cmp r12, r2 @ clamp b
+ andlo r2, r12, r2, asr #31 @
+ eorlo r2, r2, r12 @
+ cmp r12, r11 @ clamp r
+ andlo r11, r12, r11, asr #31 @
+ eorlo r11, r11, r12 @
+ cmp r12, r7, asr #1 @ clamp g
+ andlo r7, r12, r7, asr #31 @
+ eorlo r7, r7, r12 @
+ orrlo r7, r7, r7, asl #1 @
+25: @ no clamp @
+ @
+ orr r12, r2, r11, lsl #11 @ r4 = b | (r << 11)
+ orr r12, r12, r7, lsl #5 @ r4 |= (g << 5)
+ strh r12, [r0, #LCD_WIDTH]! @ store pixel
+ add r0, r0, #2*LCD_WIDTH @
+ @
+ subs r3, r3, #2 @
+ bgt 20b @ loop line 2 @
+ @
+ ldmia sp!, { r4-r12, pc } @ restore registers and return
+ .size lcd_write_yuv420_lines, .-lcd_write_yuv420_lines
diff --git a/firmware/target/arm/sandisk/sansa-e200/lcd-e200.c b/firmware/target/arm/sandisk/sansa-e200/lcd-e200.c
index 6b51531056..3e8246b367 100644
--- a/firmware/target/arm/sandisk/sansa-e200/lcd-e200.c
+++ b/firmware/target/arm/sandisk/sansa-e200/lcd-e200.c
@@ -329,115 +329,45 @@ void lcd_blit(const fb_data* data, int x, int by, int width,
(void)stride;
}
-#define CSUB_X 2
-#define CSUB_Y 2
-
-#define RYFAC (31*257)
-#define GYFAC (63*257)
-#define BYFAC (31*257)
-#define RVFAC 11170 /* 31 * 257 * 1.402 */
-#define GVFAC (-11563) /* 63 * 257 * -0.714136 */
-#define GUFAC (-5572) /* 63 * 257 * -0.344136 */
-#define BUFAC 14118 /* 31 * 257 * 1.772 */
-
-#define ROUNDOFFS (127*257)
-
-/* Performance function to blit a YUV bitmap directly to the LCD
- Actually this code is from gigabeat, because this target is also
- writing direct to a buffer. */
+/* Line write helper function for lcd_yuv_blit. Write two lines of yuv420. */
+extern void lcd_write_yuv420_lines(fb_data *dst,
+ unsigned char chroma_buf[LCD_HEIGHT/2*3],
+ unsigned char const * const src[3],
+ int width,
+ int stride);
+/* Performance function to blit a YUV bitmap directly to the LCD */
+/* For the e200 - show it rotated */
+/* So the LCD_WIDTH is now the height */
void lcd_yuv_blit(unsigned char * const src[3],
int src_x, int src_y, int stride,
- int _x, int _y, int width, int height)
+ int x, int y, int width, int height)
{
- const unsigned char *usrc;
- const unsigned char *vsrc;
- const unsigned char *ysrc;
- int xphase;
- int rc, gc, bc;
- int y, u, v;
- int red, green, blue;
- unsigned rbits, gbits, bbits;
- int count;
- fb_data *dst_row;
-
-
- width = (width + 1) & ~1;
+ /* Caches for chroma data so it only need be recaculated every other
+ line */
+ unsigned char chroma_buf[LCD_HEIGHT/2*3]; /* 480 bytes */
+ unsigned char const * yuv_src[3];
+ off_t z;
+
+ /* Sorry, but width and height must be >= 2 or else */
+ width &= ~1;
+ height >>= 1;
+
fb_data *dst = (fb_data*)lcd_driver_framebuffer +
- _x * LCD_WIDTH + (LCD_WIDTH - _y) - 1;
- fb_data *dst_last = dst - (height - 1);
+ x * LCD_WIDTH + (LCD_WIDTH - y) - 1;
+
+ z = stride*src_y;
+ yuv_src[0] = src[0] + z + src_x;
+ yuv_src[1] = src[1] + (z >> 2) + (src_x >> 1);
+ yuv_src[2] = src[2] + (yuv_src[1] - src[1]);
do
{
- dst_row = dst;
- count = width;
- ysrc = src[0] + stride * src_y + src_x;
-
- /* upsampling, YUV->RGB conversion and reduction to RGB565 in one go */
- usrc = src[1] + (stride/CSUB_X) * (src_y/CSUB_Y)
- + (src_x/CSUB_X);
- vsrc = src[2] + (stride/CSUB_X) * (src_y/CSUB_Y)
- + (src_x/CSUB_X);
- xphase = src_x % CSUB_X;
-
- u = *usrc++ - 128;
- v = *vsrc++ - 128;
- rc = RVFAC * v + ROUNDOFFS;
- gc = GVFAC * v + GUFAC * u + ROUNDOFFS;
- bc = BUFAC * u + ROUNDOFFS;
-
- do
- {
- y = *ysrc++;
- red = RYFAC * y + rc;
- green = GYFAC * y + gc;
- blue = BYFAC * y + bc;
-
- if ((unsigned)red > (RYFAC*255+ROUNDOFFS))
- {
- if (red < 0)
- red = 0;
- else
- red = (RYFAC*255+ROUNDOFFS);
- }
- if ((unsigned)green > (GYFAC*255+ROUNDOFFS))
- {
- if (green < 0)
- green = 0;
- else
- green = (GYFAC*255+ROUNDOFFS);
- }
- if ((unsigned)blue > (BYFAC*255+ROUNDOFFS))
- {
- if (blue < 0)
- blue = 0;
- else
- blue = (BYFAC*255+ROUNDOFFS);
- }
- rbits = ((unsigned)red) >> 16 ;
- gbits = ((unsigned)green) >> 16 ;
- bbits = ((unsigned)blue) >> 16 ;
-
- *dst_row = (rbits << 11) | (gbits << 5) | bbits;
-
- /* next pixel - since rotated, add WIDTH */
- dst_row += LCD_WIDTH;
-
- if (++xphase >= CSUB_X)
- {
- u = *usrc++ - 128;
- v = *vsrc++ - 128;
- rc = RVFAC * v + ROUNDOFFS;
- gc = GVFAC * v + GUFAC * u + ROUNDOFFS;
- bc = BUFAC * u + ROUNDOFFS;
- xphase = 0;
- }
- }
- while (--count);
-
- if (dst == dst_last) break;
-
- dst--;
- src_y++;
- } while( 1);
+ lcd_write_yuv420_lines(dst, chroma_buf, yuv_src, width,
+ stride);
+ yuv_src[0] += stride << 1; /* Skip down two luma lines */
+ yuv_src[1] += stride >> 1; /* Skip down one chroma line */
+ yuv_src[2] += stride >> 1;
+ dst -= 2;
+ }
+ while (--height > 0);
}
-