summaryrefslogtreecommitdiffstats
path: root/rbutil/rbutil.pro
diff options
context:
space:
mode:
Diffstat (limited to 'rbutil/rbutil.pro')
-rw-r--r--rbutil/rbutil.pro60
1 files changed, 60 insertions, 0 deletions
diff --git a/rbutil/rbutil.pro b/rbutil/rbutil.pro
new file mode 100644
index 0000000000..db3391d9a8
--- /dev/null
+++ b/rbutil/rbutil.pro
@@ -0,0 +1,60 @@
+#
+# __________ __ ___.
+# Open \______ \ ____ ____ | | _\_ |__ _______ ___
+# Source | _// _ \_/ ___\| |/ /| __ \ / _ \ \/ /
+# Jukebox | | ( <_> ) \___| < | \_\ ( <_> > < <
+# Firmware |____|_ /\____/ \___ >__|_ \|___ /\____/__/\_ \
+# \/ \/ \/ \/ \/
+#
+# All files in this archive are subject to the GNU General Public License.
+# See the file COPYING in the source tree root for full license agreement.
+#
+# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
+# KIND, either express or implied.
+#
+
+unix:!mac{
+ CCACHE = $$system(which ccache)
+ !isEmpty(CCACHE) {
+ message("using ccache at $$CCACHE")
+ QMAKE_CXX = ccache $$QMAKE_CXX
+ QMAKE_CC = ccache $$QMAKE_CC
+ }
+}
+
+TEMPLATE = subdirs
+SUBDIRS = rbutilqt ipodpatcher sansapatcher
+
+rbutilqt.depends = ipodpatcher sansapatcher
+
+
+unix:!macx {
+ LINUXDEPLOYQTURL = https://github.com/linuxdeploy/linuxdeploy-plugin-qt/releases/download/continuous/linuxdeploy-plugin-qt-x86_64.AppImage
+ LINUXDEPLOYURL = https://github.com/linuxdeploy/linuxdeploy/releases/download/continuous/linuxdeploy-x86_64.AppImage
+
+ appimage_dl.commands = \
+ curl -C- -fLO $$LINUXDEPLOYQTURL -fLO $$LINUXDEPLOYURL ; \
+ chmod +x *.AppImage; \
+ touch appimage_dl
+
+ appimage_prepare.commands = \
+ mkdir -p AppImage/usr/bin; \
+ cp sansapatcher/sansapatcher AppImage/usr/bin; \
+ cp ipodpatcher/ipodpatcher AppImage/usr/bin; \
+ cp rbutilqt/RockboxUtility AppImage/usr/bin
+
+ appimage_prepare.depends = ipodpatcher sansapatcher rbutilqt appimage_dl
+
+ appimage.commands = \
+ ./linuxdeploy-x86_64.AppImage \
+ --appdir AppImage \
+ --verbosity 2 --plugin qt --output appimage \
+ -e AppImage/usr/bin/RockboxUtility \
+ -d $$_PRO_FILE_PWD_/rbutilqt/RockboxUtility.desktop \
+ -i $$_PRO_FILE_PWD_/../docs/logo/rockbox-clef.svg
+ appimage.depends = appimage_prepare
+
+ QMAKE_EXTRA_TARGETS += appimage_dl appimage_prepare appimage
+}
+
+