summaryrefslogtreecommitdiffstats
path: root/firmware/decompressor/link.lds
blob: 51c0460d42459421de2211f9546af5c3deffe140 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
OUTPUT_FORMAT(elf32-sh)

#define DRAMORIG 0x09000000
#define DRAMSIZE (MEMORYSIZE * 0x00100000)
#define IRAMORIG 0x0f000000
#define IRAMSIZE 0x00001000

MEMORY
{
    IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
    DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
}

SECTIONS
{
    .vectors :
    {
        _loadaddress = .;
        _dramend = . + DRAMSIZE;
        KEEP(*(.vectors))
        . = ALIGN(0x200);
    } > DRAM

    .text :
    {
        *(.start)
        *(.text)
        . = ALIGN(0x4);
    } > DRAM

    .rodata :
    {
        *(.rodata*)
        *(.rodata.str1.1)
        *(.rodata.str1.4)
        . = ALIGN(0x4);
    } > DRAM

    .data :
    {
        *(.data)
        . = ALIGN(0x4);
        _iramcopy = .;
    } > DRAM

    .iram IRAMORIG : AT ( _iramcopy )
    {
        _iramstart = .;
        *(.icode)
        *(.idata)
        . = ALIGN(0x4);
        _iramend = .;
    } > IRAM

    .stack :
    {
        _stackbegin = .;
        *(.stack)
        . += 0x0800;
        _stackend = .;
    } > IRAM

    .bss :
    {
        _edata = .;
        *(.bss)
        *(COMMON)
        . = ALIGN(0x4);
        _end = .;
    } > DRAM
}