blob: cbeb7c1aaf2df59b39f8677415d353f4b0ac3065 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
|
#include "config.h"
OUTPUT_FORMAT("elf32-littlemips")
OUTPUT_ARCH(MIPS)
ENTRY(_start)
STARTUP(target/mips/ingenic_jz47xx/crt0.o)
INPUT(target/mips/exception-mips.o)
INPUT(target/mips/system-mips.o)
#define STUBOFFSET 0x4000
#define DRAMORIG (0x80000000 + STUBOFFSET)
#define DRAMSIZE (MEMORYSIZE * 0x100000 - STUBOFFSET)
#define IRAMORIG 0x80000000
#define IRAMSIZE 16K
/* End of the audio buffer, where the codec buffer starts */
#define ENDAUDIOADDR (DRAMORIG + DRAMSIZE - PLUGIN_BUFFER_SIZE - CODEC_SIZE)
/* Where the codec buffer ends, and the plugin buffer starts */
#define ENDCODECADDR (ENDAUDIOADDR + CODEC_SIZE)
MEMORY
{
DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
}
SECTIONS
{
. = DRAMORIG;
.startup :
{
loadaddress = .;
_loadaddress = .;
*(.startup.text);
} > DRAM
.text :
{
*(.text*);
} > DRAM
. = ALIGN(4);
.rodata :
{
*(.rodata*);
} > DRAM
. = ALIGN(4);
.data :
{
*(.data*);
*(.sdata*);
} > DRAM
/* Set the load address of .iram at the same address as .bss
* so RAM won't be wasted as .iram in the end will get copied
* to IRAM. */
.iram IRAMORIG: AT (_edata)
{
_iramstart = .;
KEEP(*(.vectors.1));
. = 0x100;
KEEP(*(.vectors.2));
. = 0x180;
KEEP(*(.vectors.3));
. = 0x200;
KEEP(*(.vectors.4));
KEEP(*(.vectors));
*(.icode*);
*(.irodata);
*(.idata);
KEEP(*(.vectors))
*(.vectors);
_iramend = .;
} > IRAM
_iramcopy = LOADADDR(.iram);
. = ALIGN(4);
.stack (NOLOAD):
{
*(.stack);
stackbegin = .;
. += 0x1d00;
stackend = .;
_irqstackbegin = .;
. += 0x400;
_irqstackend = .;
} > IRAM
.bss (NOLOAD):
{
_edata = .;
*(.sbss*);
*(.bss*);
*(.ibss*); /* Don't put this in IRAM as there's not enough space */
*(COMMON);
*(.scommon*);
_end = .;
} > DRAM
.audiobuf :
{
. = ALIGN(4);
audiobuffer = .;
} > DRAM
audiobufend = ENDAUDIOADDR;
codecbuf = ENDAUDIOADDR;
pluginbuf = ENDCODECADDR;
/DISCARD/ :
{
*(.MIPS.abiflags);
*(.eh_frame);
*(.rel.dyn);
}
}
|
