summaryrefslogtreecommitdiffstats
path: root/firmware/target/mips/ingenic_jz47xx/boot.lds
blob: b6f3e169fb39f9e526158d3db4a5f52131d230d5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
#include "config.h"
#undef mips

OUTPUT_FORMAT("elf32-littlemips")
OUTPUT_ARCH(MIPS)
ENTRY(_start)
STARTUP(target/mips/ingenic_jz47xx/crt0.o)

#define DRAMSIZE (MEMORYSIZE * 0x100000)

#define DRAMORIG 0x80004000
#define IRAMORIG 0x80000000
#define IRAMSIZE 16K

MEMORY
{
   DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
   IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
}

SECTIONS
{
    . = DRAMORIG;

    .text :
    {
        loadaddress = .;
        _loadaddress = .;
        *(.init.text);
        *(.text*);
        *(.glue_7);
        *(.glue_7t);
        *(.rel.dyn);
    } > DRAM
    
    .vectors :
    {
        _vectorsstart = .;
        KEEP(*(.vectors))
        *(.vectors);
    } > DRAM
    
    . = ALIGN(4);

    .rodata :
    {
        *(.rodata);  /* problems without this, dunno why */
        *(.rodata*);
        *(.rodata.str1.1);
        *(.rodata.str1.4);
        . = ALIGN(0x4);

        /* Pseudo-allocate the copies of the data sections */
        _datacopy = .;
    } > DRAM

    .data :
    {
        *(.icode);
        *(.irodata);
        *(.idata);
        *(.data*);
        *(.sdata*);
        . = ALIGN(0x4);
        _dataend = . ;
    } > DRAM
    
    _gp = ALIGN(16);
    .got :
    {
        *(.got*)
    } > DRAM
    
    . = ALIGN(4);

    .bss :
    {
         _edata = .;
         *(.sbss*);
         *(.bss*);
         *(.ibss);
         *(COMMON)
         *(.scommon*);
         _end = .;
    } > DRAM
    
    .iram IRAMORIG:
    {
        . = 0x220; /* Vectors take in 0x80000000 -> 0x80000220 */
        _iramstart = .;
        *(.icode)
        *(.irodata)
        *(.idata)
        . = ALIGN(0x4);
        _iramend = .;
    } > IRAM AT> DRAM

    _iramcopy = LOADADDR(.iram);

    .ibss (NOLOAD) :
    {
        _iedata = .;
        *(.ibss)
        . = ALIGN(0x4);
        _iend = .;
    } > IRAM
    
    .stack :
    {
         *(.stack)
         . = ALIGN(0x4);
         _stackbegin = .;
         stackbegin = .;
         . += 0x2000;
         _stackend = .;
         stackend = .;
    } > IRAM
}