summaryrefslogtreecommitdiffstats
path: root/flash/bootloader/no_rom.lds
blob: e65e7fdd3cfe2ffe328b38e7f73fcf0e7e13debe (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
/* This is for the variant without boot ROM,
   where the flash ROM is mirrored to address zero */

OUTPUT_FORMAT(elf32-sh)
INPUT(bootloader.o)

MEMORY
{
	IRAM : ORIGIN = 0x0FFFF000, LENGTH = 0x1000
	FLASH : ORIGIN = 0x00000000, LENGTH = 0x40000
}

SECTIONS
{
	.vectors :
	{
		*(.vectors)
		. = ALIGN(0x200);
	} > FLASH

	.startup :
	{
		*(.startup)
		. = ALIGN(0x4);
		_begin_iramcopy = .;
	} > FLASH

	.text : AT ( _begin_iramcopy )
	{	 
		_begin_text = .;
		*(.text)	
		. = ALIGN(0x4);
		_end_text = .;
	} > IRAM
	
	.data : AT ( _end_text )
	{
		_begin_data = .;
		*(.data)
		. = ALIGN(0x4);
		_end_data = .;
	} > IRAM

	.bss : AT ( _end_data )
	{
		_begin_bss = .;
		*(.bss)
		. = ALIGN(0x4);
		_end_bss = .;
	} > IRAM

	.stack :
	{
		_begin_stack = .;
		*(.stack)
		. = ALIGN(0x1000);
		_end_stack = .;
	} > IRAM

	/* size of the program (without vectors) */
	_total_size = SIZEOF(.startup) + SIZEOF(.text) + SIZEOF(.data);
}