summaryrefslogtreecommitdiffstats
path: root/utils/hwstub/stub/atj213x/hwstub.lds
blob: 7f5c9fae18dac6a99a08aa754e106ff50d0493cd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
#include "config.h"
ENTRY(main)
OUTPUT_ARCH(mips)
STARTUP(atj213x/crt0.o)

MEMORY
{
    DRAM : ORIGIN = DRAM_ORIG, LENGTH = DRAM_SIZE
    IRAM : ORIGIN = IRAM_ORIG, LENGTH = IRAM_SIZE
}

SECTIONS
{
  .init.text :
        {
            _irqbase = .;
            relocstart = .;
            oc_codestart = .;
            *(.init.text*)
        } > IRAM

  .exception.text (IRAM_ORIG + 0x200) :
        {
            *(.irq_vector*)
        } > IRAM

  .text :
	{
	    *(.text*)
            *(.icode*)
	} > IRAM

  .data :
	{
            *(.rodata*)
	    *(.data*)
            *(.rel.dyn)
            relocend = .;
	} > IRAM

  .stack (NOLOAD) :
        {
            . = ALIGN(4);
            stackbegin = .;
            oc_stackstart = .;
            . += 0x2000;
            stackend = .;
            irqstackbegin = .;
            . += 0x400;
            irqstackend = .;
            oc_stackend = .;
        } > IRAM

  .bss (NOLOAD) :
	{
            bssbegin = .;
            *(.sbss*)
	    *(.bss*)
	    *(COMMON)
            *(.scommon*)
            bssend = .;
            oc_codeend = .;
            oc_bufferstart = .;
	} > IRAM

  .end IRAM_ORIG+IRAM_SIZE (NOLOAD) :
  {
      oc_bufferend = .;
  } > IRAM
}