summaryrefslogtreecommitdiffstats
path: root/utils/regtools/qeditor/qeditor.pro
blob: 0ec7c3dde11e2ae3882b3a339432622e05752a64 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
QT += widgets

HEADERS += mainwindow.h backend.h regtab.h analyser.h settings.h \
    std_analysers.h utils.h regdisplaypanel.h regedit.h
SOURCES += main.cpp mainwindow.cpp regtab.cpp backend.cpp analyser.cpp \
    std_analysers.cpp settings.cpp utils.cpp regdisplaypanel.cpp regedit.cpp
LIBS += -L../lib/ -lsocdesc -lxml2
INCLUDEPATH += ../include/ ../../hwstub/lib
DEPENDPATH += ../

libsocdesc.commands = cd ../lib && make
QMAKE_EXTRA_TARGETS += libsocdesc
PRE_TARGETDEPS += libsocdesc

VERSION = 3.0.0

DEFINES += APP_VERSION=\\\"$$VERSION\\\"

unix {
    !nohwstub {
        message("Use 'qmake -config nohwstub' if you want to disable hwstub support")
        libhwstub.commands = cd ../../hwstub/lib && make
        QMAKE_EXTRA_TARGETS += libhwstub
        PRE_TARGETDEPS += libhwstub

        LIBS += -L../../hwstub/lib -lhwstub
        DEPENDPATH += ../../hwstub
        DEFINES += HAVE_HWSTUB
        CONFIG += link_pkgconfig
        PKGCONFIG += libusb-1.0
    }
}

CONFIG += debug